d5f9cf4f19
Docs: * https://developer.android.com/build/publish-library/configure-pub-variants#single-pub-var * https://developer.android.com/reference/tools/gradle-api/8.0/com/android/build/api/dsl/PublishingOptions This resolves the following warning from Android Gradle Plugin 7.2.2 and helps unblock the upgrade to AGP 8.0.1: > Software Components will not be created automatically for Maven > publishing from Android Gradle Plugin 8.0. To opt-in to the future > behavior, set the Gradle property > `android.disableAutomaticComponentCreation=true` in the > `gradle.properties` file or use the new publishing DSL. > > Affected Modules: `lib-cast`, `lib-common`, `lib-container`, > `lib-database`, `lib-datasource`, `lib-datasource-cronet`, > `lib-datasource-okhttp`, `lib-datasource-rtmp`, `lib-decoder`, > `lib-effect`, `lib-exoplayer`, `lib-exoplayer-all (legacy)`, > `lib-exoplayer-dash`, `lib-exoplayer-hls`, `lib-exoplayer-ima`, > `lib-exoplayer-rtsp`, `lib-exoplayer-smoothstreaming`, > `lib-exoplayer-workmanager`, `lib-extractor`, `lib-media2 (legacy)`, > `lib-mediasession (legacy)`, `lib-muxer`, `lib-session`, > `lib-transformer`, `lib-ui`, `lib-ui-leanback`, `test-utils`, > `test-utils-robolectric` Issue: androidx/media#409 PiperOrigin-RevId: 533464133
83 lines
3.6 KiB
Groovy
83 lines
3.6 KiB
Groovy
// Copyright (C) 2017 The Android Open Source Project
|
|
//
|
|
// Licensed under the Apache License, Version 2.0 (the "License");
|
|
// you may not use this file except in compliance with the License.
|
|
// You may obtain a copy of the License at
|
|
//
|
|
// http://www.apache.org/licenses/LICENSE-2.0
|
|
//
|
|
// Unless required by applicable law or agreed to in writing, software
|
|
// distributed under the License is distributed on an "AS IS" BASIS,
|
|
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
// See the License for the specific language governing permissions and
|
|
// limitations under the License.
|
|
|
|
apply plugin: 'maven-publish'
|
|
apply from: "$gradle.ext.androidxMediaSettingsDir/missing_aar_type_workaround.gradle"
|
|
|
|
afterEvaluate {
|
|
if (rootProject.name == gradle.ext.androidxMediaProjectName) {
|
|
publishing {
|
|
repositories {
|
|
maven {
|
|
url = findProperty('mavenRepo') ?: "${buildDir}/repo"
|
|
}
|
|
}
|
|
publications {
|
|
release(MavenPublication) {
|
|
from components.release
|
|
groupId = 'androidx.media3'
|
|
artifactId = findProperty('releaseArtifactId') ?: ''
|
|
version = findProperty('releaseVersion') ?: ''
|
|
configurations.create("sourcesElement") { variant ->
|
|
variant.visible = false
|
|
variant.canBeResolved = false
|
|
variant.attributes.attribute(
|
|
Usage.USAGE_ATTRIBUTE,
|
|
project.objects.named(Usage, Usage.JAVA_RUNTIME))
|
|
variant.attributes.attribute(
|
|
Category.CATEGORY_ATTRIBUTE,
|
|
project.objects.named(Category, Category.DOCUMENTATION))
|
|
variant.attributes.attribute(
|
|
Bundling.BUNDLING_ATTRIBUTE,
|
|
project.objects.named(Bundling, Bundling.EXTERNAL))
|
|
variant.attributes.attribute(
|
|
DocsType.DOCS_TYPE_ATTRIBUTE,
|
|
project.objects.named(DocsType, DocsType.SOURCES))
|
|
components.release.addVariantsFromConfiguration(variant) {}
|
|
}
|
|
pom {
|
|
name =
|
|
findProperty('releaseName')
|
|
?: ''
|
|
description =
|
|
findProperty('releaseDescription')
|
|
?: findProperty('releaseName')
|
|
?: ''
|
|
licenses {
|
|
license {
|
|
name = 'The Apache Software License, Version 2.0'
|
|
url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
|
|
distribution = 'repo'
|
|
}
|
|
}
|
|
developers {
|
|
developer {
|
|
name = 'The Android Open Source Project'
|
|
}
|
|
}
|
|
scm {
|
|
connection = 'scm:git:https://github.com/androidx/media.git'
|
|
url = 'https://github.com/androidx/media'
|
|
}
|
|
withXml {
|
|
addMissingAarTypeToXml(it)
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
tasks.withType(PublishToMavenRepository) { it.dependsOn lint, test }
|