889f435a49
The only dependencies that are not updated are the ones that need to be kept in sync with other system (like Android source tree) or would require a Kotlin dependency in common or exoplayer modules. As a side effect, some demo apps now need a Kotlin config and some additional modules require desugaring/multidex logic. To simplify the setup, the desugaring and multidex steps are added to the common config. PiperOrigin-RevId: 527243950
74 lines
3.2 KiB
Groovy
74 lines
3.2 KiB
Groovy
// Copyright (C) 2016 The Android Open Source Project
|
|
//
|
|
// Licensed under the Apache License, Version 2.0 (the "License");
|
|
// you may not use this file except in compliance with the License.
|
|
// You may obtain a copy of the License at
|
|
//
|
|
// http://www.apache.org/licenses/LICENSE-2.0
|
|
//
|
|
// Unless required by applicable law or agreed to in writing, software
|
|
// distributed under the License is distributed on an "AS IS" BASIS,
|
|
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
// See the License for the specific language governing permissions and
|
|
// limitations under the License.
|
|
apply from: "$gradle.ext.androidxMediaSettingsDir/common_library_config.gradle"
|
|
|
|
android {
|
|
defaultConfig {
|
|
// The following argument makes the Android Test Orchestrator run its
|
|
// "pm clear" command after each test invocation. This command ensures
|
|
// that the app's state is completely cleared between tests.
|
|
testInstrumentationRunnerArguments clearPackageData: 'true'
|
|
}
|
|
|
|
buildTypes {
|
|
debug {
|
|
testCoverageEnabled = true
|
|
}
|
|
}
|
|
|
|
sourceSets {
|
|
androidTest.assets.srcDir '../test_data/src/test/assets'
|
|
test.assets.srcDir '../test_data/src/test/assets/'
|
|
}
|
|
}
|
|
|
|
dependencies {
|
|
api project(modulePrefix + 'lib-common')
|
|
// TODO(b/203754886): Revisit which modules are exported as API dependencies.
|
|
api project(modulePrefix + 'lib-datasource')
|
|
api project(modulePrefix + 'lib-decoder')
|
|
api project(modulePrefix + 'lib-extractor')
|
|
api project(modulePrefix + 'lib-database')
|
|
implementation 'androidx.annotation:annotation:' + androidxAnnotationVersion
|
|
implementation 'androidx.core:core:' + androidxCoreVersion
|
|
compileOnly 'com.google.code.findbugs:jsr305:' + jsr305Version
|
|
compileOnly 'org.checkerframework:checker-qual:' + checkerframeworkVersion
|
|
compileOnly 'org.checkerframework:checker-compat-qual:' + checkerframeworkCompatVersion
|
|
compileOnly 'org.jetbrains.kotlin:kotlin-annotations-jvm:' + kotlinAnnotationsVersion
|
|
compileOnly 'com.google.errorprone:error_prone_annotations:' + errorProneVersion
|
|
androidTestImplementation 'androidx.test:runner:' + androidxTestRunnerVersion
|
|
androidTestImplementation 'com.linkedin.dexmaker:dexmaker:' + dexmakerVersion
|
|
androidTestImplementation 'com.linkedin.dexmaker:dexmaker-mockito:' + dexmakerVersion
|
|
androidTestImplementation(project(modulePrefix + 'test-utils')) {
|
|
exclude module: modulePrefix.substring(1) + 'library-core'
|
|
}
|
|
androidTestImplementation 'com.squareup.okhttp3:mockwebserver:' + okhttpVersion
|
|
testCompileOnly 'org.checkerframework:checker-compat-qual:' + checkerframeworkCompatVersion
|
|
testImplementation 'com.squareup.okhttp3:mockwebserver:' + okhttpVersion
|
|
testImplementation 'org.robolectric:robolectric:' + robolectricVersion
|
|
testImplementation project(modulePrefix + 'test-utils')
|
|
testImplementation project(modulePrefix + 'test-utils-robolectric')
|
|
}
|
|
|
|
ext {
|
|
javadocTitle = 'Core module'
|
|
}
|
|
apply from: '../../javadoc_library.gradle'
|
|
|
|
ext {
|
|
releaseArtifactId = 'media3-exoplayer'
|
|
releaseName = 'Media3 ExoPlayer module'
|
|
}
|
|
apply from: '../../publish.gradle'
|