// Copyright (C) 2017 The Android Open Source Project
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//      http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
apply from: '../../constants.gradle'
apply plugin: 'com.android.library'

android {
    compileSdkVersion project.ext.compileSdkVersion
    buildToolsVersion project.ext.buildToolsVersion

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    defaultConfig {
        minSdkVersion project.ext.minSdkVersion
        targetSdkVersion project.ext.targetSdkVersion
        consumerProguardFiles 'proguard-rules.txt'
    }
}

dependencies {
    api 'com.google.ads.interactivemedia.v3:interactivemedia:3.9.4'
    implementation project(modulePrefix + 'library-core')
    implementation 'com.google.android.gms:play-services-ads:15.0.1'
    // These dependencies are necessary to force the supportLibraryVersion of
    // com.android.support:support-v4 and com.android.support:customtabs to be
    // used. Else older versions are used, for example via:
    // com.google.android.gms:play-services-ads:15.0.1
    // |-- com.android.support:customtabs:26.1.0
    implementation 'com.android.support:support-v4:' + supportLibraryVersion
    implementation 'com.android.support:customtabs:' + supportLibraryVersion
    testImplementation 'com.google.truth:truth:' + truthVersion
    testImplementation 'junit:junit:' + junitVersion
    testImplementation 'org.mockito:mockito-core:' + mockitoVersion
    testImplementation 'org.robolectric:robolectric:' + robolectricVersion
    testImplementation project(modulePrefix + 'testutils-robolectric')
}

apply plugin: 'com.google.android.gms.strict-version-matcher-plugin'

ext {
    javadocTitle = 'IMA extension'
}
apply from: '../../javadoc_library.gradle'

ext {
    releaseArtifact = 'extension-ima'
    releaseDescription = 'Interactive Media Ads extension for ExoPlayer.'
}
apply from: '../../publish.gradle'